; BANKUTL.PPE - Written by Dan Shore
;               SysOp - The Shoreline BBS
;               October 29, 1996
;
; Purpose     - To have one program for access to all the
;               other Bank Free Utilities (BankEdit, BankEd
;               and BankPack)
;
; To install:
;
;    1) Edit your CMD.LST file(s) to add this:
;
;                             Charges Per     PPE/MNU File Specification -or-
;            Command    Sec  Minute    Use    Keystroke Substitution
;        ══════════════ ═══ ═════════════════ ═════════════════════════════════
;     1) BANKUTL        110        0        0 C:\PCB\PPE\BANK\BANKUTL.PPE
;
;       Note: You may have to change the pathname to the PPE.
;       Note: You may have to change the security level of the PPE.
;
;
; NOTE:  Make sure the security level is high enough for only SysOp's
;        and Co-SysOp's to access this program.
;
;
; NOTE:  When using BANKUTL, you no longer need entries in your CMD.LST
;        for BANKPACK, BANKEDIT, or BANKED.
;
;    ***  Make sure you have BANKEDIT, BANKPACK, BANKUTL, & BANK
;         are all in the SAME directory!!!!!
;
;────────────────────────────────────────────────────────────────────────────
STRING user_input             ' User response
STRING main_prompt            ' Prompt Variable
STRING bank_txt               ' External Text file
;────────────────────────────────────────────────────────────────────────────

'
'  Define external text file - Support Language Files
'
bank_txt = PPEPATH() + "BANKTXT2" + LANGEXT()

'
'  Stay in loop until user quits the program (hits enter)
'
WHILE (1) DO
   '
   '  Display the Utility Menu
   '
   GOSUB DISP_MENU
   '
   '  Default response is nothing
   '
   user_input = ""
   '
   '  Prompt the User
   '
   main_prompt =  READLINE(bank_txt, 91)
   INPUTSTR main_prompt, user_input, @X07, 1, "123", LFAFTER+UPCASE+GUIDE+FIELDLEN+ERASELINE
   '
   '  Process users response
   '
   SELECT CASE user_input
     '
     '  Run the .CFG Editor
     '
     CASE "1"
       CALL PPEPATH() + "BANKED.PPE"
     '
     '  Run the User Editor
     '
     CASE "2"
       CALL PPEPATH() + "BANKEDIT.PPE"
     '
     '  Run the Packer
     '
     CASE "3"
       '
       '  Make sure user wants to run packer
       '
       main_prompt = READLINE(bank_txt, 92)
       user_input = NOCHAR()
       INPUTYN main_prompt, user_input, @X07
       '
       '  Run packer if they respond yes
       '
       IF (user_input = YESCHAR()) CALL PPEPATH() + "BANKPACK.PPE"
     '
     '  Exit program
     '
     CASE ""
       GOTO EXIT_PROG
   END SELECT
END WHILE

'
'  Clear the screen and display Utilities Menu
'
:DISP_MENU
  CLS
  NEWLINES 5
  DISPFILE PPEPATH() + "utlmnu", LANG+GRAPH+SEC
  RETURN

'
'  Get out of here!!
'
:EXIT_PROG
  END