;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; finger.ppe for EWHO
; written by drew [pwa]
;
; this is a quickie "finger" type of ppe used as an example with EWHO.
; this ppe expects the user's name as a parameter.  for example, if you
; were to install this in your cmd.lst, someone would run this like:
;
;         finger john doe
;
; this ppe can be compiled with pplc 2.0 (which is preferred since it
; loads a lot quicker than 3.x ppe's).
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

string uname
int numtok, recnum
 
; get the name of user to finger
while (tokcount()) do
    uname = uname + " " + gettoken()
endwhile

; zap any leading and trailing spaces (in case name wasn't passed in
; properly for whatever reason
uname = ltrim(uname, " ")
uname = rtrim(uname, " ")

; get the record #.  if user exists, get their stats
recnum = u_recnum(uname)
if (recnum == -1) then
    println "@X0CNo such user : " + uname
    wait
    end
endif
getaltuser u_recnum(uname)

; print the user's stats
defcolor
println "@CLS@@X0F    ____/\_________________________        __________________________________@X07"
println "@X0C   /    /   _/  _____/_  ___/   _  \      /   ____\_____/   _ \_____/  _____/@X07"
println "@X04  /    /    \___   \_/  __|_|  |/ _/      \___  \_ /   \   |/  \    \___   \_@X07"
println "@X07 /    /    /        /  /    |      \     /        \     \   _   |    \       \@X07"
println "@X08 \________/\_______/\_______|___|\  \    \_______/\_____/___|   /____/_______/@X07"
println "@X08                                 |__/                       |__/@X07"
println "@X0C■@X08──────────────────────────────────────────────────────────────[ finger.ppe ]─@X0C■"
println "@X08│   @X0FUs@X0Cer@X04 Handle@X08.........@X04: @X07" + u_name() + "@POS:79@@X08│"
println "@X08│   @X0FUs@X0Cer@X04 Note@X08...........@X04: @X07" + u_city + "@POS:79@@X08│"
println "@X08│   @X0FSe@X0Ccu@X04rity Level@X08......@X04: @X07" + string(u_sec) + "@POS:79@@X08│"
println "@X08│   @X0FTi@X0Cme@X04s On System@X08.....@X04: @X07" + string(u_logons()) + "@POS:79@@X08│"
println "@X08│   @X0FCa@X0Cll@X04er Number@X08.......@X04: @X07@NUMCALLS@@POS:79@@X08│"
println "@X08│                                                                             @X08│"
println "@X08│   @X0FFi@X0Cle@X04s DL'ed@X08.........@X04: @X07" + string(u_fdl()) + \
        "@POS:40@@X0FBy@X0Cte@X04s DL'ed@X08.........@X04: @X07" + \
        string(tounsigned(u_bdl())) + "@POS:79@@X08│"
println "@X08│   @X0FFi@X0Cle@X04s UL'ed@X08.........@X04: @X07" + string(u_ful()) + \
        "@POS:40@@X0FBy@X0Cte@X04s UL'ed@X08.........@X04: @X07" + \
        string(tounsigned(u_bul())) + "@POS:79@@X08│"
println "@X0C■@X08─────────────────────────────────────────────────────────────────────────────@X0C■"

; release active user stats for pcboard
frealtuser
wait