/*
* - Installation Hardcopy (der Benutzer gibt alle Angaben vor)
*
* letzte Änderung: xx.xx.xxxx / Weckmann
*
*/
DialogLoggingOff
CreateBackground 'SwSetup - Hardcopy Installation'
DialogOut 'SwSetup - Hardcopy Installation'
// ----------- Installation über das netzwerk oder einem vorgegebenen Verzeichnis
// ----------- Installation from the network or from a named directory
// vInstallDirVon = 'd:\\SwSetup\\Hardcopy'
// ----------- Installation aus dem aktuellen Verzeichnis
// ----------- Installation from the actual directory
vInstallDirVon = pwd
// -------------------------------------------------------
vLogFileName = '%__WindowsVerzeichnis__%\\Hardcopy.log'
fp = fopen vLogFileName 'w'
If __error__ == 0
MessageBox 'Logdatei ''%vLogFileName%'' kann nicht geöffnet werden'
Exit
EndIf
Fehler = 0
fputs fp '\nInstallation Hardcopy\n\n'
fputs fp 'Datum/Uhrzeit: \t%__Date__%\n'
fputs fp ' WinVersion: \t%__WinVersion__%\n'
fputs fp ' WinMinor: \t%__WinMinor__%\n'
fputs fp ' WinSystem: \t%__WinSystem__%\n'
fputs fp '\n'
:NeuerVersuch
vText = 'Please select a directory'
If __Language__ == 'deu'
vText = 'Bitte Verzeichnis auswählen'
EndIf
cd 'c:\\'
vDir = SelectDir 'c:\\Hardcopy' vText
If __error__ == 0
fputs fp 'Der Benutzer hat die Installation abgebrochen !\n'
Exit
EndIf
mkdir vDir
If __error__ == 0
vText = 'Unable to create the directory !'
If __Language__ == 'deu'
vText = 'Verzeichnis kann nicht angelegt werden'
EndIf
fputs fp '%vText%\n'
MessageBox vText
GoTo :NeuerVersuch
EndIf
fputs fp 'Installation von: %vInstallDirVon%\n'
fputs fp 'Installation nach: %vDir%\n\n'
if __WinSystem__ == 'NT'
CopyFile '%vInstallDirVon%\\files\\HcpNTdll.dll' '%vDir%\\HcpNTdll.Dll' fp
Fehler = Fehler | __Error__
CopyFile '%vInstallDirVon%\\files\\HrdCpy32.exe' '%vDir%\\Hardcopy.exe' fp
Fehler = Fehler | __Error__
else // windows95 oder windows 3.n
CopyFile '%vInstallDirVon%\\files\\HcpDll.dll' '%vDir%\\HcpDll.Dll' fp
Fehler = Fehler | __Error__
CopyFile '%vInstallDirVon%\\files\\Hardcopy.exe' '%vDir%\\Hardcopy.exe' fp
Fehler = Fehler | __Error__
endif
fputs fp '\n'
// ------------ Program-group
:NeuerVersuch2
vText = 'Hardcopy - Print Screen'
vText2 = 'Please select a Program Group'
If __Language__ == 'deu'
vText = 'Hardcopy - Bildschirmausdruck'
vText2 = 'Bitte eine Programmgruppe auswählen'
EndIf
vPrgGrp = SelectProgramGroup vText vText2
If __error__ == 0
fputs fp 'Der Benutzer hat die Installation abgebrochen !\n'
Exit
EndIf
// ------------ Hardcopy
CreateItem '\\PG\\%vPrgGrp%' 'Hardcopy' '%vDir%\\Hardcopy.exe' '' '%vDir%' '%vDir%\\Hardcopy.exe' 0 1
If __error__ == 0
vText = 'Error, can not create program-icon/group'
If __Language__ == 'deu'
vText = 'Programm-Icon/Gruppe kann nicht angelegt werden'
EndIf
fputs fp '%vText%\n'
MessageBox vText
GoTo :NeuerVersuch2
EndIf
fputs fp 'Ok: CreateItem "%vPrgGrp%" ---> Hardcopy\n'
// ------------ Readme
vReadme = 'ReadMe'
If __Language__ == 'deu'
vReadme = 'LiesMich'
EndIf
CopyFile '%vInstallDirVon%\\files\\%vReadme%.txt' '%vDir%\\%vReadme%.txt' fp
CreateItem '\\PG\\%vPrgGrp%' vReadme 'notepad' '%vDir%\\%vReadme%.txt' '%vDir%' 'notepad.exe' 0 0
If __error__ == 0
Fehler = 1
vText = 'Error, can not create program-icon/group for %vReadme%.txt'
If __Language__ == 'deu'
vText = 'Programm-Icon/Gruppe "%vReadme%.txt" kann nicht angelegt werden'
EndIf
fputs fp '%vText%\n'
MessageBox vText
Else
fputs fp 'Ok: CreateItem "%vPrgGrp%" ---> %vReadme%\n'
EndIf
// ------------ Uninstall Hardcopy with Icon
vUninst = 'Uninstall Hardcopy'
If __Language__ == 'deu'
vUninst = 'Hardcopy entfernen'
EndIf
CreateItem '\\PG\\%vPrgGrp%' vUninst '%__WindowsVerzeichnis__%\\SwSetupi.exe' '%__WindowsVerzeichnis__% %__WindowsVerzeichnis__%\\hardcopy.del' '%__WindowsVerzeichnis__%' '%__WindowsVerzeichnis__%\\SwSetup3.exe' 0 0
If __error__ == 0
Fehler = 1
vText = 'Error, can not create program-icon for %vUninst%'
If __Language__ == 'deu'
vText = 'Programm-Icon "%vUninst%" kann nicht angelegt werden'
EndIf
fputs fp '%vText%\n'
MessageBox vText
Else
fputs fp 'Ok: CreateItem "%vPrgGrp%" ---> %vUninst%\n'
EndIf
CopyFile '%vInstallDirVon%\\SwSetupi.exe' '%__WindowsVerzeichnis__%\\SwSetupi.exe' fp
If __System32__ == 0
CopyFile '%vInstallDirVon%\\SwSetup3.exe' '%__WindowsVerzeichnis__%\\SwSetup3.exe' fp
Else
CopyFile '%vInstallDirVon%\\SwSetup.exe' '%__WindowsVerzeichnis__%\\SwSetup.exe' fp
EndIf
fpDel = fopen '%__WindowsVerzeichnis__%\\hardcopy.del' 'w'
If __error__ == 0
fputs fp 'Logdatei ''%vDir%\\hardcopy.del'' kann nicht geöffnet werden\n'
MessageBox 'Logdatei ''%vDir%\\hardcopy.del'' kann nicht geöffnet werden'
Fehler = 1
EndIf
vT1 = 'Uninstall Hardcopy'
vT2 = 'This will remove "Hardcopy".\\nDo you wish continue ?'
vT3 = 'Hardcopy removed.'
If __Language__ == 'deu'
vT1 = 'Hardcopy entfernen'
vT2 = 'Möchten Sie tatsächlich Hardcopy entfernen ?'
vT3 = 'Hardcopy wurde entfernt !'
EndIf
fputs fpDel 'DialogOut ''%vT1%''\n'
fputs fpDel 'MessageBox ''%vT2%'' 36\n'
fputs fpDel 'If __error__ == 6\n'
fputs fpDel ' DeleteFile ''%vDir%\\\\HcpNTdll.Dll''\n'
fputs fpDel ' DeleteFile ''%vDir%\\\\Hardcopy.exe''\n'
fputs fpDel ' DeleteFile ''%vDir%\\\\HcpDll.Dll''\n'
fputs fpDel ' DeleteFile ''%vDir%\\\\Liesmich.txt''\n'
fputs fpDel ' rmdir ''%vDir%''\n'
fputs fpDel ' DeleteFile ''%__WindowsVerzeichnis__%\\\\hardcopy.del''\n'
fputs fpDel ' DeleteFile ''%__WindowsVerzeichnis__%\\\\hardcopy.ini''\n'
fputs fpDel ' CreateItem ''-\\\\PG\\\\%vPrgGrp%'' ''Hardcopy'' '''' '''' '''' '''' 0 0\n'
fputs fpDel ' CreateItem ''-\\\\PG\\\\%vPrgGrp%'' ''%vReadme%'' '''' '''' '''' '''' 0 0\n'
fputs fpDel ' CreateItem ''-\\\\PG\\\\%vPrgGrp%'' ''%vUninst%'' '''' '''' '''' '''' 0 0\n'
fputs fpDel ' MessageBox ''%vT3%''\n'
fputs fpDel 'EndIf\n'
// ------------
fputs fp '\nEnde\n'
If Fehler != 0
vText = '\r\nError by installation, will you see the installation-log ?'
If __Language__ == 'deu'
vText = '\r\nBei der Installation ist ein Fehler aufgetreten,\r\nsoll die Installations-Logdatei angezeigt werden ?'
EndIf
MessageBox vText 36
If __error__ == 6
Exec 'notepad %vLogFileName%'
EndIf
Endif
If Fehler == 0
vText = 'Setup is complete. You may run the Hardcopy program.'
If __Language__ == 'deu'
vText = 'Die Installation ist Ok, Sie können nun das Programm Hardcopy starten.'
Endif
MessageBox vText
EndIf
fclose fp
