Metropoli BBS - memberremove.asp

VIEWER: memberremove.asp MODE: TEXT (ASCII)
<!--#include file="session.inc"-->
<%
' Role Administrator
' memberremove.asp
' Copyright (c) Microsoft Corporation 1993-1998. All rights reserved.

' ******************************************************************************
' This file removes members from Role Performer DL's using ADSI.  The list of
' members are selected from a select list created in the perfomeredit.asp file.
' ******************************************************************************


On Error Resume Next
Response.Expires = 0

%>
<HTML>
<HEAD>
<TITLE>Role Administrator</TITLE>
</HEAD>
<BODY BACKGROUND="back.jpg" BGCOLOR="#FFFF99" TEXT="#000000" LINK="#000000" VLINK="#000000">

<SCRIPT LANGUAGE="JavaScript">
<%

Dim strRole         ' current selected Role
Dim strPerformer    ' current selected Role Performer
Dim strMember       ' string array of selected members to add to the Role performer
Dim blnFoundString  ' Does the Member string contain a valid ADsPath to a Member object
Dim intMemberPos    ' current location of parsing index of the Member string
Dim intFirst        ' index to the first character in a vaild ADsPath string
Dim intLast         ' index to the last character in a valid ADsPath string
Dim strIADsPath     ' ADsPath string to the Member object
Dim objPerformer    ' the current Performer object
Dim objMember       ' the current Member object

strRole = Replace(Request.Form("ROLE"), "ldap", "LDAP")
strPerformer = Replace(Request.Form("PERFORMER"), "ldap", "LDAP")
strMember = Replace(Request.Form("MEMBER"), "ldap", "LDAP")

blnFoundString = False

If Len(strMember) <> 0 Then
  For intMemberPos = 1 To Len(strMember)
    If Mid(strMember, intMemberPos, 4) = "LDAP" Then
      If blnFoundString Then
        intLast = intMemberPos - 2
        strIADsPath = Mid(strMember, intFirst, intLast - intFirst)
        Set objPerformer = GetObject(strPerformer)
        If Err.Number <> 0 Then
          displayError "Failed to get ADSI object:\n" & strPerformer, 0, 0
        End If
        Set objMember = GetObject(strIADsPath)
        If Err.Number <> 0 Then
          displayError "Failed to get ADSI object:\n" & strIADsPath, 0, 0
        End If
        objPerformer.Remove objMember.ADsPath
        If Err.Number <> 0 Then
          displayError "Failed to remove ADSI object:\n" & strIADsPath & "\nfrom ADSI object:\n" & strPerformer, 0, 0
        End If
        intFirst = intMemberPos
      Else
        blnFoundString = True
        intFirst = intMemberPos
      End If
    End If
  Next
  If blnFoundString Then
    intLast = Len(strMember) + 1
    strIADsPath = Mid(strMember, intFirst, intLast - intFirst)
    Set objPerformer = GetObject(strPerformer)
    If Err.Number <> 0 Then
      displayError "Failed to get ADSI object:\n" & strPerformer, 0, 0
    End If
    Set objMember = GetObject(strIADsPath)
    If Err.Number <> 0 Then
      displayError "Failed to get ADSI object:\n" & strIADsPath, 0, 0
    End If
    objPerformer.Remove objMember.ADsPath
    If Err.Number <> 0 Then
        displayError "Failed to remove ADSI object:\n" & strIADsPath & "\nfrom ADSI object:\n" & strPerformer, 0, 0
    End If
  End If
End If
%>
window.location="performeredit.asp?ROLE=<%=encodePath(strRole)%>&PERFORMER=<%=encodePath(strPerformer)%>"
</SCRIPT>
</BODY>
</HTML>
[ RETURN TO DIRECTORY ]