<% @ LANGUAGE=VBSCRIPT CODEPAGE = 1252 %>
<!--#include file="constant.inc"-->
<!--#include file="lib/session.inc"-->
<% SendHeader 0, 1 %>
<!--#include file="lib/getrend.inc"-->
<!--#include file="lib/pageutil.inc"-->
<%
'<!-- Microsoft Outlook Web Access-->
'<!-- Root.asp : Frameset for the Inbox window -->
'<!-- Copyright (c) Microsoft Corporation 1993-1997. All rights reserved.-->
On Error Resume Next
If Request.QueryString("mode") <> "" Then
Response.Redirect bstrVirtRoot + "/inbox/Main_fr.asp?" + Request.QueryString()
End If
L_OutlookBar_FRAME_Width_Number = 75 'changes width of the Outlook Menu Bar
urlString = Request.QueryString()
if urlString <> "" then urlString="?"+urlString
CheckSession2 bstrVirtRoot + "/root.asp" + urlString
urlAcs = Request.QueryString("acs") '$ acs=anon for anon login's
urlObj = Request.QueryString("obj") '$ This is what we want to pass to the child frames
urlStore = Request.QueryString("store")
urlView = Request.QueryString("view") '$ This is the current view; we need to communicate
'$ this down if specified. The default is 1,
If urlView ="" then '$ so if the view=1 is missing, set the variable
urlView = 1 '$ to 1 anyway
End if
If urlAcs<>"anon" And Not Session(bstrAuthenticated) Then
urlAcs = "anon" 'prevents anon users from manually removing acs=anon from url
End If
SetSessionStuff '$ I don't have to do this here, but it makes
'$ tuning the UI on different platforms easier.
bstrNavbarFile = bstrVirtRoot + "/Navbar/nbInbox.asp"
'gotta figger out what store if not told
if urlAcs="anon" Then
iStore=1 'no private store or cal for anon users
bstrNavbarFile = bstrVirtRoot + "/Navbar/nbAnon.asp"
ElseIf urlStore = "" Then 'no store on url
If urlObj="" Then 'no folder on url (first logon)
iStore = 0 'default to private store inbox folder
Else 'authenticated with folderID only (need to open the folder and get the store)
OpenAllStores
PubStoreID=Session(bstrPublicStoreID)
Set objFolder = objOMSession.GetFolder(urlObj,PubStoreID)
If objFolder Is Nothing Then
iStore=0
ElseIf IsEmpty(objFolder.ID) Then
iStore=0
Else
iStore=1
End If
End If
Else
iStore=cint(urlStore) 'authenticated 0,1 or 2=calendar, 3=contacts
End If
bstrDefaultCalendarFolderID=objOMSession.GetDefaultFolder(0).ID
bstrDefaultContactsFolderID=objOMSession.GetDefaultFolder(5).ID
%>
<!DOCTYPE HTML PUBLIC "-//IETF//DTD HTML 3.2//EN">
<HTML>
<HEAD>
<SCRIPT LANGUAGE="Javascript">
<%
' Get the IIS Version Number. Password changing is only supported
' in version 4 or greater.
if fEnablePasswordMenu then
Set objRenderMsg = GetMessageRenderer
soft = Request.ServerVariables("SERVER_SOFTWARE")
posver = Instr(soft, "/")
serverVersion = CInt(right(soft, len(soft)-posver))
if serverVersion > 29 then serverVersion = serverVersion/10 ' German VBS call "cint(3.0)" returns a value of 30.
if serverVersion > 3 then
dim days
days = Request.ServerVariables("HTTP_REQ_PWD_EXPIRE")
if days = "" then days = 10000
if cint(days) < 0 then days = 10000
If (cint(days) < iNotificationPeriod) and (not urlAcs = "anon") then
%>alert("<%objRenderMsg.write L_PasswordExpire_Text + days + L_PasswordExpire2_Text, response %>");<%
End If
End If
End If
%>
var hold_szCurPubFID="";
var hold_szCurPvtFID="";
var fNeedReload = true;
var contactsFID = "<%=bstrDefaultContactsFolderID%>";
var iNavStore=0;
var iCalView=1;
var szCurFolderID="";
var szCurYr = "";
var szCurMo = "";
var szCurDa = "";
function composePick(iSelIdx) {
iCurCompose=iSelIdx;
}
function RefreshNavbar(iStore) {
MF = self.main_fr;
if (iStore != 2 && fNeedReload==true) { //LEAVING CALENDAR or CONTACT VIEWS
fNeedReload = false;
if (iStore==0) { //CAL TO PRI STORE
MF.location="<%=bstrVirtRoot%>/inbox/main_fr.asp?store=0&obj="+hold_szCurPvtFID;
}
else if (iStore==3) { //CAL TO CONTACTS
MF.location="<%=bstrVirtRoot%>/contacts/main_fr.asp?store=0&obj=" + contactsFID;
fNeedReload = true;
}
else { //CAL TO PUB STORE
MF.location="<%=bstrVirtRoot%>/inbox/main_fr.asp?store=1&obj="+hold_szCurPubFID;
}
}else{
if (iStore == 3) { // GOTO TOP OF Contacts
MF.location="<%=bstrVirtRoot%>/contacts/main_fr.asp?store=0&obj=" + contactsFID;
fNeedReload = true;
}else if (iStore!=2){ // GOTO TOP OF Public or Private Folders
MF.command_fr.location="<%=bstrVirtRoot%>/inbox/commands.asp?store="+iStore+"&command=newfolder";
}else { // REFRESH CAL
self.main_fr.location="<%=bstrVirtRoot%>/calendar/main_fr.asp?view="+iCalView+"&obj=<%=bstrDefaultCalendarFolderID%>";
fNeedReload = true;
}
}
MF.iCurStore=iStore;
if (iStore != 3 && iStore != 2) NavStore=iStore;
}
var fRedirect = 0;
function SetRedirectFlag(bFlag) {
fRedirect=bFlag;
}
</SCRIPT>
<TITLE><%=L_MSOutlookWebAccess_StaticText%></TITLE>
</HEAD>
<FRAMESET COLS="<%=L_OutlookBar_FRAME_Width_Number%>,*" frameborder=1 border=5>
<FRAME SRC="<%=bstrNavbarFile%>" name="navbar_fr" marginheight=0 marginwidth=0 scrolling=auto>
<%If iStore=2 Then 'render calendar view %>
<FRAME SRC="<%=bstrVirtRoot%>/calendar/main_fr.asp?view=<%=urlView%>&obj=<%=bstrDefaultCalendarFolderID%>" name="main_fr" marginheight=0 marginwidth=0>
<%ElseIf iStore=3 Then 'render contacts view %>
<FRAME SRC="<%=bstrVirtRoot%>/contacts/main_fr.asp?view=<%=urlView%>&store=0&obj=<%=urlObj%>&acs=<%=urlAcs%>" name="main_fr" marginheight=0 marginwidth=0>
<%Else 'render private/public folder view %>
<FRAME SRC="<%=bstrVirtRoot%>/inbox/main_fr.asp?view=<%=urlView%>&store=<%=iStore%>&obj=<%=urlObj%>&acs=<%=urlAcs%>" name="main_fr" marginheight=0 marginwidth=0>
<%End If%>
</FRAMESET>
<body text=000000>
<NOFRAMES>
Microsoft Outlook Web Access must be viewed on a browser that supports frames. <br>
To obtain such a browser, please click <a href="http://www.microsoft.com/ie/download/" target="_blank">here</a> to
download the Microsoft <a href="http://www.microsoft.com/ie/download" target="_blank"><b>Internet Explorer</a>.</b> </p>
</NOFRAMES>
</body>
</HTML>
