<% @ LANGUAGE=VBSCRIPT CODEPAGE = 1252 %>
<!--#include file="../constant.inc"-->
<!--#include file="../lib/getrend.inc"-->
<!--#include file="../lib/session.inc"-->
<%
SendHeader 0, 0
'<!--Microsoft Outlook Web Access-->
'<!--LogonFrm.asp-->
'<!--Copyright (c) Microsoft Corporation 1993-1997. All rights reserved.-->

On Error Resume Next

CheckSession

szAttach = Request.QueryString("att")
nPos = InStr(1, szAttach, "-", 0)
nPos = InStr(nPos+1, szAttach, "-", 0)
nPos2 = InStr(nPos+1, szAttach, "-", 0)
If nPos2 = 0 Then
	nPos2 = Len(szAttach)+1
End If

szRecordKey = Mid(szAttach, nPos+1, nPos2-(nPos+1))
szAttachName = Mid(szAttach, nPos2+1)

szObj = Request.QueryString("obj")
Set objOneMsg = Session(szObj)
If objOneMsg Is Nothing then
	Set objOneMsg = OpenMessage(szObj)

  If objOneMsg is Nothing then
	  ReportError1 L_errCannotGetMessageObj_ErrorMessage 
  ElseIf	objOneMsg.ID = "" then
	  ReportError1 L_errMessageDeleted_ErrorMessage
  End If
End If

Set objAttach = objOneMsg.Attachments.Item(szRecordKey)
if objAttach is Nothing then
	ReportError1 L_errFailGettingAttachment_ErrorMessage
End If
bstrFileName = ""
If isWin32 or isUnix then
    bstrFileName=  objAttach.Fields(ActMsgPR_ATTACH_LONG_FILENAME)
    If bstrFileName = "" then
       bstrFileName =  objAttach.Fields(ActMsgPR_ATTACH_FILENAME)
    End If 
Else
    bstrFileName =  objAttach.Fields(ActMsgPR_ATTACH_FILENAME) 
End If	
If bstrFileName = "" then
    bstrFileName = objAttach.Name
End If

Response.Addheader "Content-Disposition", "attachment;filename=" + bstrFileName
Set objRenderAtt = GetMessageRenderer
objRenderAtt.DataSource = objAttach

objRenderAtt.RenderProperty ActMsgPR_ATTACH_DATA_BIN, 0, Response
If Err.Number <> 0 then
	ReportError1 L_errRenderPropError_ErrorMessage
End If
%>