@echo off
set QEo=
if "%QEc%"=="" goto dont
if "%QEx%"=="" goto dont
if "%1"=="" goto usage
if exist *.tmp del *.tmp
set QCo=
set QCf=
set QCl=
goto top

:dont
echo This BAT file is used internally by QLIB.  Do not use directly!
goto end

:top
if "%1"=="/d" goto addopt
if "%1"=="/p" goto addopt
if "%1"=="/wx" goto addopt
if "%1"=="/b" goto addopt
if "%1"=="/w" goto addopt
if "%1"=="/c" goto addopt
if "%1"=="/m" goto addopt
goto cont
:addopt
set QCo=%QCo% %1
shift
goto top
:cont
if exist %1.obj del %1.obj
if exist %1.exe del %1.exe

call %QEc%2obj %1
echo.
if not exist %1.obj goto end
set QCf=%1
shift
:top2
set QCl=%QCl% %1
shift
if not "%1"=="" goto top2

call qlink %QCo% %QCf% %QCf%.obj %QCl%

if not exist %QCf%.exe goto end

goto done

:usage
echo Usage : %QEc%2EXE [options] file file(s)
echo   file = file to compile (do not give .%QEx% extension)
echo   file(s) = files to linked together (full filenames)  [OBJs and LIBs]
echo   DOS Extender options:
echo    /p = use PMODE/W DOS extender (default)
echo    /d = use DOS/4GW DOS extender
echo    /wx = use WDOSX DOS extender
echo   Math LIBs options:
echo    /b = use Borland/VisC Math LIBs %QEmb%
echo    /w = use Watcom Math LIBs %QEmw%
echo   Other options:
echo    /c = use PMWLITE to compress EXE
echo    /m = generate map file (*.map)
echo.         

:done
if exist *.tmp del *.tmp

:end
set QCo=
set QCf=
set QCl=
set QEc=
set QEx=
set QEmb=
set QEmw=