************************************************************
        ***                                                      ***
        *** PAN script for adding an opening menu to Lotus 1-2-3 ***
        ***          (Tested only with version 2.01)             ***
        ***                                                      ***
        ************************************************************

IfLoad "c:\123\123.exe"
Else
	Output "^M^J^GPAN is unable to load Lotus 1-2-3.  Please edit the file 123.PAN and^M^J"
	Output "correct the 'IfLoad' command to include the appropriate pathname for PAN to^M^J"
	Output "locate the file 123.EXE on your PC."
	Quit
EndIf
Go ""

* Wait for Lotus 1-2-3 to initialize

WaitScreen 0 75 "READY"

* Draw the menu in reverse video

Video 70
Screen 07 30 / ╔═══════════════════════╗ /
Screen 08 30 / ║ Select a spreadsheet: ║ /
Screen 09 30 / ║      1. Expenses      ║ /
Screen 10 30 / ║      2. Income        ║ /
Screen 11 30 / ║      3. Budget        ║ /
Screen 12 30 / ╚═══════════════════════╝ /

* Get and interpret a keypress

Video 07
Label try_again
Flush
GetKey
IfKey "1"
	* Select: Worksheet Erase Yes to clear the menu
	Key "/wey"
	* Select: File Retrieve to load a spreadsheet
	Key "/frexpenses[Enter]"
	Jump out
EndIf
IfKey "2"
	Key "/wey"
	Key "/frincome[Enter]"
	Jump out
EndIf
IfKey "3"
	Key "/wey"
	Key "/frbudget[Enter]"
	Jump out
EndIf
IfKey "[Esc]"
	Key "/wey"
	Jump out
EndIf
Output "^G"
Jump try_again

* Out

Label out
WaitChild
Quit