.key idir,p2,p3,p4,p5,p6,p7,p8
.bra {
.ket }

; AmigaFax Install script.
;
; USAGES:   Double click the Install_Now (or Install_Demo) icon,
;               or click it once then double click the destination drawer.
;
;  In a Shell window, change to the appropriate directory,
;          eg    cd df0:AFaxDemo
;            or  cd df0:AmigaFax
;            then type either
;                install disk:drawer
;            or  install

assign AmiFax: ""

if not "{idir}" eq ""
  if not "{idir}" eq "afax:"

    if "{idir}" eq "q"
      echo "Installation cancelled."
      skip to_end
    endif
  
    if "{idir}" eq "n"
      echo "Installation cancelled."
      skip to_end
    endif
  
    if not "{p2}" eq ""
      echo "*N*N*N **** ERROR ****  No double quotes around: {idir} {p2}..."
      skip to_redo
    endif
  
    echo >ram:faxfname {idir}
    search >nil: ram:faxfname ":"
    if warn
      delete >nil: ram:faxfname
      echo "*N*N*N **** ERROR ****  Missing *":*" in {idir}."
      skip to_redo
    endif
    delete >nil: ram:faxfname

    if exists "{idir}"
      echo "*N{idir} already exists!"
      ask "Assign afax: to it and continue (y/n)?"
      if not warn
        skip to_redo
      endif
      assign afax: "{idir}"
      if not exists {idir}.info
        if exists AmiFax:/AmigaFax.info
          copy >nil: AmiFax:/AmigaFax.info {idir}.info nopro
	else
          if exists AmiFax:/AFaxDemo.info
            copy >nil: AmiFax:/AFaxDemo.info {idir}.info nopro
	  else
            copy >nil: AmiFax:docs.info {idir}.info nopro
          endif
        endif
      endif
      skip to_install
    else
      ask "*NCreate {idir}, assign afax: to it and continue (y/n)?"
      if not warn 
        skip to_redo
      endif
      makedir {idir}
      if warn 
        skip to_redo
      endif
      if exists AmiFax:/AmigaFax.info
        copy >nil: AmiFax:/AmigaFax.info {idir}.info nopro
      else
        if exists AmiFax:/AFaxDemo.info
          copy >nil: AmiFax:/AFaxDemo.info {idir}.info nopro
        else
          copy >nil: AmiFax:docs.info {idir}.info nopro
        endif
      endif
      assign afax: "{idir}"
      skip to_install
    endif
  endif
endif


assign >nil: afax: exists  
if not warn
  echo "*NThe existing afax assignment is:"
  assign afax: exists
  ask "Do you want to install AmigaFax in this directory (y/n)? "
  if warn
    skip to_install
  endif
endif
skip to_redo

lab to_install

echo "*NDirectory afax:s"
if exists afax:s
  copy AmiFax:s afax:s nopro
  echo "The Afax:s directory already existed!"
  echo "NOT overwriting files you may have edited:"
  dir AmiFax:s.user
  wait 5 secs
else
  copy AmiFax:s afax:s nopro
  copy AmiFax:s.user afax:s nopro
endif
protect >nil: afax:s/AFAX-Startup +s

delete afax:s/User-Startup
echo >ram:fstart "assign afax: {idir}"

assign >nil: uucp: exists
if not warn
  join ram:fstart AmiFax:s/User-Startup as afax:s/User-Startup
else
  join ram:fstart AmiFax:s/User-Startup AmiFax:s/UUCPStart as afax:s/User-Startup
endif

delete ram:fstart

echo  "*NDirectory afax:lib"
if exists afax:lib
  if exists AmiFax:lib
    copy AmiFax:lib afax:lib nopro
  endif
  echo "The afax:lib directory already exists!"
  echo "NOT overwriting files you may have edited:"
  dir AmiFax:lib.user
  wait 5 secs
  if exists AmiFax:lib.user/afax.library
    if exists afax:lib/afax.library
      if exists afax:lib/afax.library.old
        delete afax:lib/afax.library.old
      endif
      rename afax:lib/afax.library afax:lib/afax.library.old
      copy AmiFax:lib.user/afax.library afax:lib/afax.library
      echo "*NExisting Licence Library renamed afax:lib/afax.library.old"
      echo "*NYou will need to flush or reboot to load new licence"
      wait 2 secs
    else
      copy AmiFax:lib.user/afax.library afax:lib/afax.library
      echo "*Nafax:lib/afax.library (Registration Library) copied"
    endif
  endif
else
  makedir afax:lib
  if exists AmiFax:lib
    copy AmiFax:lib afax:lib nopro
  endif
  copy AmiFax:lib.user afax:lib nopro
endif
wait 2 secs


echo "*NDirectory afax:"
copy AmiFax:#?fax#? afax: nopro
copy AmiFax:READ#?  afax: nopro
copy AmiFax:DEMO#?  afax: nopro

echo "*NDirectory afax:Docs"
if not exists afax:Docs.info
  copy AmiFax:Docs.info afax:Docs.info nopro
endif
copy AmiFax:Docs afax:Docs nopro

echo "*NDirectory afax:c"
copy AmiFax:c afax:c nopro

echo "*NAfax Printer Driver"
if exists afax:c/afax.driver
  copy afax:c/afax.driver DEVS:Printers/afax.driver nopro
endif
if exists afax:c/afax.driver.debug
  copy afax:c/afax.driver.debug DEVS:Printers/afax.driver.debug nopro
endif

echo    "*NDirectory afax:libs"
copy AmiFax:libs afax:libs nopro

echo "*NDirectory afax:l"
copy AmiFax:l afax:l nopro

echo    "*NDirectory afax:devs"
copy AmiFax:devs afax:devs nopro

echo "*NDirectory afax:faxdoc"
copy AmiFax:faxdoc afax:faxdoc nopro

echo "*NDirectory afax:incoming"
copy AmiFax:incoming afax:incoming nopro

echo "*NDirectory afax:spool"
copy AmiFax:spool afax:spool nopro

echo "*NDirectory afax:REXX"
copy AmiFax:spool afax:REXX nopro

echo "*NDirectory afax:uucp"
copy AmiFax:uucp afax:uucp nopro

echo "*NDirectory afax:uucp/s"
copy AmiFax:uucp/s afax:uucp/s nopro

echo "*NDirectory afax:uucp/c"
copy AmiFax:uucp/c afax:uucp/c nopro

echo "*NDirectory afax:Other"
copy AmiFax:Other afax:Other nopro

echo  "*NDirectory afax:uucp/lib"
if exists afax:uucp/lib
  echo "The afax:uucp/lib directory already exists!"
  echo "NOT overwriting files you may have edited:"
  dir AmiFax:uucp/lib
  wait 5 secs
else
  copy AmiFax:uucp/lib afax:uucp/lib nopro
endif

if not exists l:null-handler
  ask "Install l:null-handler (y/n)?"
  if warn
    copy afax:l/null-handler l:
  endif
endif

if not exists l:fifo-handler
  ask "Install fifo-handler and fifo.library (y/n)?"
  if warn
    copy afax:l/fifo-handler l:
    copy afax:libs/fifo.library libs:
  endif
endif

if not exists libs:arp.library
  ask "Install arp.library (y/n)?"
  if warn
    copy afax:libs/arp.library libs:
  endif
endif

if exists AmiFax:FaxFonts.run
  echo "*NIf you are not using AmigaDOS2.0, you may wish to extract the"
  echo "larger CM fax fonts into your FONTS: directory. Under 2.0 you can"
  echo "scale standard fonts, so this is not necessary. You can do it manually"
  echo "later if you want."
  ask "*NDo you want the FaxFonts extracted to FONTS: (y/n)?"
  if warn
    cd fonts:
    AmiFax:FaxFonts.run
  endif
endif

echo "*NDirectory afax:BBS"
if not exists afax:BBS.info
  if exists AmiFax:BBS.info
    copy AmiFax:BBS.info afax:BBS.info nopro
  endif
endif
if exists AmiFax:BBS
  copy AmiFax:BBS afax:BBS all
endif

echo "*NAFax Assigns"
execute afax:s/AFaxAssign

echo "*NInstallation complete."
echo "You now must edit configuration files in the s and lib directories"
echo "See the README file for instructions."
ask "*NPress return to continue."
skip to_end

lab to_redo
echo "*NEnter the name of the disk and drawer"
echo "where you want to install AmigaFax.  Type a colon between"
echo "disk and drawer parts and enclose it all in double quotes."
echo "Example: *"Work:fax*" (q=quit): " noline
execute >nil: AmiFax:install ?
lab to_end