%%HP: T(3)A(D)F(.);
DIR
\|^Z
DIR
Z11 10
Z12 25.2
Z21 33
Z22 32
M
\<< Z11 Z12
Z21 Z22 { 2 2 }
\->ARRY
\>>
M\->
\<< "Z" M\->.P
\>>
END
\|^Y
DIR
Y11
-6.25488663018E-2
Y12
4.92572322127E-2
Y21
6.45035183737E-2
Y22
-1.95465207193E-2
M
\<< Y11 Y12
Y21 Y22 { 2 2 }
\->ARRY
\>>
M\->
\<< "Y" M\->.P
\>>
END
\|^A
DIR
A11
.30303030303
A12
-15.503030303
A21
.030303030303
A22
.969696969697
M
\<< A11 A12
A21 A22 { 2 2 }
\->ARRY
\>>
M\->
\<< "A" M\->.P
\>>
END
\|^H
DIR
H11 -15.9875
H12 .7875
H21 -1.03125
H22 .03125
M
\<< H11 H12
H21 H22 { 2 2 }
\->ARRY
\>>
M\->
\<< "h" M\->.P
\>>
END
\|^G
DIR
G11 .1
G12 -2.52
G21 3.3
G22 -51.16
M
\<< G11 G12
G21 G22 { 2 2 }
\->ARRY
\>>
M\->
\<< "g" M\->.P
\>>
END
\|^S
DIR
S11
1.14084507042
S12
-.107554417414
S21
-.140845070423
S22
1.04694835681
M
\<< S11 S12
S21 S22 { 2 2 }
\->ARRY
\>>
M\->
\<< "S" M\->.P
\>>
END
Z1.Z2
DIR
\->ZE
\<< UPDIR
DTAG 'ZE' STO Z1.Z2
\>>
\->ZA
\<< UPDIR
DTAG 'ZA' STO Z1.Z2
\>>
Z1
\<< ZA \-> za
\<< UPDIR
\|^Z Z11 Z12 Z21 *
Z22 za + / - \->NUM
UPDIR Z1.Z2 "Z1"
\->TAG
\>>
\>>
Z2
\<< ZE \-> ze
\<< UPDIR
\|^Z Z22 Z12 Z21 *
Z11 ze + / - \->NUM
UPDIR Z1.Z2 "Z2"
\->TAG
\>>
\>>
Y1
\<< ZA \-> za
\<< UPDIR
\|^Y Y11 Y12 Y21 *
Y22 za INV + / -
\->NUM UPDIR Z1.Z2
"Y1" \->TAG
\>>
\>>
Y2
\<< ZE \-> ze
\<< UPDIR
\|^Y Y22 Y12 Y21 *
Y11 ze INV + / -
\->NUM UPDIR Z1.Z2
"Y2" \->TAG
\>>
\>>
END
VU
DIR
\->ZA
\<< UPDIR
DTAG 'ZA' STO VU
\>>
vu
\<< ZA \-> za
\<< UPDIR
\|^Y Y21 NEG Y22 za
INV + / \->NUM UPDIR
VU "vu" \->TAG
\>>
\>>
vu.dB
\<< vu ABS
LOG 20 * "vu[dB]"
\->TAG
\>>
END
A.DB
DIR
\->RI
\<< UPDIR
DTAG 'Ri' STO A.DB
\>>
\->RA
\<< UPDIR
DTAG 'Ra' STO A.DB
\>>
a.dB
\<< Ri Ra \->
ze za
\<< UPDIR
\|^Z Z11 ze + Z22 za
+ * Z21 / Z12 - ABS
2 ^ 4 / ze / za /
LOG 10 * UPDIR A.DB
"a[dB]" \->TAG
\>>
\>>
END
R1.R2
DIR
\->RE
\<< UPDIR
DTAG 're' STO R1.R2
\>>
\->RA
\<< UPDIR
DTAG 'ra' STO R1.R2
\>>
r1
\<< ra \-> RA
\<< UPDIR
\|^S S12 S21 * RA * 1
S22 RA * - / S11 +
\->NUM UPDIR R1.R2
"r1" \->TAG
\>>
\>>
r2
\<< re \-> RE
\<< UPDIR
\|^S S12 S21 * RE * 1
S11 RE * - / S22 +
\->NUM UPDIR R1.R2
"r2" \->TAG
\>>
\>>
END
A.DB.MIT.RA.REELL
DIR
\->RA
\<< UPDIR
DTAG 'ra' STO
A.DB.MIT.RA.REELL
\>>
a.dB
\<< ra \-> RA
\<< UPDIR
\|^S 1 RA S22 * - ABS
2 ^ S21 ABS 2 ^ 1
RA 2 ^ - * / LOG 10
* \->NUM UPDIR
A.DB.MIT.RA.REELL
"a[dB]" \->TAG
\>>
\>>
END
BILDER
DIR
TR.
\<<
" TR-Schaltung
--------Z2--
Z1
------------
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TR-Schaltung in Y
1 + 1 -1
Z1 Z2 Z2
-1 1
Z2 Z2
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TR-Schaltung in Z
Z1 Z1
Z1 Z1+Z2
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TR-Schaltung in A
1 Z2
1 1+(Z2)
Z1 (Z1)
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TR-Schaltung in H
(Z1Z2) Z1
(Z1+Z2) (Z1+Z2)
-(Z1) 1
(Z1+Z2) (Z1+Z2)
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TR-Schaltung in G
1 -1
Z1
1 Z1+Z2
"
CLLCD 1 DISP 7
FREEZE
\>>
TL.
\<<
" TL-Schaltung
--Z1--------
Z2
------------
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TL-Schaltung in Y
1 -1
Z1 Z1
-1 1 + 1
Z1 Z1 Z2
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TL-Schaltung in Z
Z1+Z2 Z2
Z2 Z2
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TL-Schaltung in A
1+(Z1) Z1
(Z2)
1 1
Z2
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TL-Schaltung in H
Z1 1
-1 1
Z2
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" TL-Schaltung in G
1 -(Z2)
(Z1+Z2) (Z1+Z2)
(Z2) (Z1Z2)
(Z1+Z2) (Z1+Z2)
"
CLLCD 1 DISP 7
FREEZE
\>>
T.
\<<
" T-Schaltung
--Z1----Z3--
Z2
------------
K=Z1Z2+Z1Z3+Z2Z3
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" T-Schaltung in Y
(Z2+Z3) -(Z2)
(K) (K)
-(Z2) (Z1+Z2)
(K) (K)
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" T-Schaltung in Z
Z1+Z2 Z2
Z2 Z2+Z3
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" T-Schaltung in A
1+(Z1) Z1+Z3+(Z1Z3)
(Z2) (Z2)
1 1+(Z3)
Z2 (Z2)
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" T-Schaltung in H
(K) (Z2)
(Z2+Z3) (Z2+Z3)
-(Z2) 1
(Z2+Z3) (Z2+Z3)
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" T-Schaltung in G
1 -(Z2)
(Z1+Z2) (Z1+Z2)
(Z2) Z3+(Z1Z2)
(Z1+Z2) (Z1+Z2)
"
CLLCD 1 DISP 7
FREEZE
\>>
PI.
\<<
" PI-Schaltung
-----Z2-----
Z1 Z3
------------
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" PI-Schaltung in Y
1 + 1 -1
Z1 Z2 Z2
-1 1 + 1
Z2 Z2 Z3
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" PI-Schaltung in Z
Z1(Z2+Z3) Z1Z3
(Z1+Z2+Z3) (Z1+Z2+Z3)
Z1Z3 Z3(Z1+Z2)
(Z1+Z2+Z3) (Z1+Z2+Z3)
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" PI-Schaltung in A
1+(Z2) (Z2)
(Z3)
1 + 1 + Z2 1+(Z2)
Z1 Z3 Z1Z3 (Z1)
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" PI-Schaltung in H
(Z1Z2) (Z1)
(Z1+Z2) (Z1+Z2)
-(Z1) (Z1+Z2+Z3)
(Z1+Z2) Z3(Z1+Z2)
"
CLLCD 1 DISP
DO 7
FREEZE
UNTIL KEY
END DROP
" PI-Schaltung in G
(Z1+Z2+Z3) -(Z3)
Z1(Z2+Z3) (Z2+Z3)
(Z2) (Z2Z3)
(Z2+Z3) (Z2+Z3)
"
CLLCD 1 DISP 7
FREEZE
\>>
END
\->Z
\<< DTAG4 \-> Z11
Z12 Z21 Z22
\<< Z11 Z12 Z21
Z22 Z\|v Z11 Z12 Z21
Z22 { 2 2 } \->ARRY
DET \-> DETZ
\<< Z22 Z12
NEG Z21 NEG Z11 { 2
2 } \->ARRY DETZ /
OBJ\-> DROP Y\|v Z11
DETZ 1 Z22 { 2 2 }
\->ARRY Z21 / OBJ\->
DROP A\|v DETZ Z12
Z21 NEG 1 { 2 2 }
\->ARRY Z22 / OBJ\->
DROP H\|v 1 Z12 NEG
Z21 DETZ { 2 2 }
\->ARRY Z11 / OBJ\->
DROP G\|v SBER 2 MENU
\>>
\>>
\>>
\->Y
\<< DTAG4 \-> Y11
Y12 Y21 Y22
\<< Y11 Y12 Y21
Y22 Y\|v Y11 Y12 Y21
Y22 { 2 2 } \->ARRY
DET \-> DETY
\<< Y22 Y12
NEG Y21 NEG Y11 { 2
2 } \->ARRY DETY /
OBJ\-> DROP Z\|v Y22 1
DETY Y11 { 2 2 }
\->ARRY Y21 NEG /
OBJ\-> DROP A\|v 1 Y12
NEG Y21 DETY { 2 2
} \->ARRY Y11 / OBJ\->
DROP H\|v DETY Y12
Y21 NEG 1 { 2 2 }
\->ARRY Y22 / OBJ\->
DROP G\|v SBER 2 MENU
\>>
\>>
\>>
\->A
\<< DTAG4 \-> A11
A12 A21 A22
\<< A11 A12 A21
A22 A\|v A11 A12 A21
A22 { 2 2 } \->ARRY
DET \-> DETA
\<< A11 DETA
1 A22 { 2 2 } \->ARRY
A21 / OBJ\-> DROP Z\|v
A22 DETA NEG -1 A11
{ 2 2 } \->ARRY A12 /
OBJ\-> DROP Y\|v A12
DETA -1 A21 { 2 2 }
\->ARRY A22 / OBJ\->
DROP H\|v A21 DETA
NEG 1 A12 { 2 2 }
\->ARRY A11 / OBJ\->
DROP G\|v SBER 2 MENU
\>>
\>>
\>>
\->H
\<< DTAG4 \-> H11
H12 H21 H22
\<< H11 H12 H21
H22 H\|v H11 H12 H21
H22 { 2 2 } \->ARRY
DET \-> DETH
\<< DETH H12
H21 NEG 1 { 2 2 }
\->ARRY H22 / OBJ\->
DROP Z\|v 1 H12 NEG
H21 DETH { 2 2 }
\->ARRY H11 / OBJ\->
DROP Y\|v DETH H11
H22 1 { 2 2 } \->ARRY
H21 NEG / OBJ\-> DROP
A\|v H22 H12 NEG H21
NEG H11 { 2 2 }
\->ARRY DETH / OBJ\->
DROP G\|v SBER 2 MENU
\>>
\>>
\>>
\->G
\<< DTAG4 \-> G11
G12 G21 G22
\<< G11 G12 G21
G22 G\|v G11 G12 G21
G22 { 2 2 } \->ARRY
DET \-> DETG
\<< 1 G12 NEG
G21 DETG { 2 2 }
\->ARRY G11 / OBJ\->
DROP Z\|v DETG G12
G21 NEG 1 { 2 2 }
\->ARRY G22 / OBJ\->
DROP Y\|v 1 G22 G11
DETG { 2 2 } \->ARRY
G21 / OBJ\-> DROP A\|v
G22 G12 NEG G21 NEG
G11 { 2 2 } \->ARRY
DETG / OBJ\-> DROP H\|v
SBER 2 MENU
\>>
\>>
\>>
\->S
\<< DTAG4 \-> S11
S12 S21 S22
\<< S11 S12 S21
S22 { 2 2 } \->ARRY
DET \-> DETS
\<< 1 S11 +
S22 - DETS - S12 2
* S21 2 * 1 S11 -
S22 + DETS - { 2 2
} \->ARRY 1 S11 - S22
- DETS + / OBJ\->
DROP Z\|v \|^Z Z11 Z12
Z21 Z22 UPDIR \->Z
S11 S12 S21 S22 S\|v
\>>
\>>
\>>
Z\|v
\<< \|^Z 'Z22' STO
'Z21' STO 'Z12' STO
'Z11' STO UPDIR
\>>
Y\|v
\<< \|^Y 'Y22' STO
'Y21' STO 'Y12' STO
'Y11' STO UPDIR
\>>
A\|v
\<< \|^A 'A22' STO
'A21' STO 'A12' STO
'A11' STO UPDIR
\>>
H\|v
\<< \|^H 'H22' STO
'H21' STO 'H12' STO
'H11' STO UPDIR
\>>
G\|v
\<< \|^G 'G22' STO
'G21' STO 'G12' STO
'G11' STO UPDIR
\>>
S\|v
\<< \|^S 'S22' STO
'S21' STO 'S12' STO
'S11' STO UPDIR
\>>
DTAG4
\<< 4 ROLL DTAG 4
ROLL DTAG 4 ROLL
DTAG 4 ROLL DTAG
\>>
SBER
\<< \|^Z Z11 Z12
Z21 Z22 \-> Z11 Z12
Z21 Z22
\<< Z11 Z12 Z21
Z22 { 2 2 } \->ARRY
DET \-> DETZ
\<< -1 Z11 +
Z22 - DETZ + Z12 2
* Z21 2 * -1 Z11 -
Z22 + DETZ + { 2 2
} \->ARRY 1 Z11 + Z22
+ DETZ + / OBJ\->
DROP UPDIR S\|v
\>>
\>>
\>>
ZE 50
ZA 1000
Ri 500
Ra 1000
re 7
ra 1000
M\->.P
\<< \-> A
\<< DTAG OBJ\->
DROP 4 ROLL A "11"
+ \->TAG 4 ROLL A
"12" + \->TAG 4 ROLL
A "21" + \->TAG 4
ROLL A "22" + \->TAG
\>>
\>>
CST { \->Z \->Y \->A \->H
\->G \->S }
END
