%%HP: T(3)A(R)F(.);
DIR
CB
DIR
FREQresp '
dBmag=Fresp'
POWresp.EQ {
'Pmax=Presp' PEmax
}
SPLresp.EQ {
'SPLmax=K2+40*LOG(F
/Fb)' 'PeakSPL+
Fresp' }
DESIGN.EQ { '
Vb=Vas/Vr' 'Fb=Qr*
Fs' 'F3dB=Qr*Fs*\v/((
1/Qb^2-2+\v/((1/Qb^2-
2)^2+4))/2)' '
dBpeak=20*LOG(Amax)
' 'Fmax=(345_m/s)/(
\pi*.83*Dia)' 'Amax=
IFTE(Qb>INV(\v/2),SQ(
Qb)/\v/(SQ(Qb)-.25),1
)' 'Vr=Qr^2-1' 'Qr=
1/Qts/(1/Qb-.1)' '
K1=(4*\pi^3*1.18_kg/m
^3)*Fb^4*Vd^2/345_m
/s' 'Par=K1/Amax^2'
'K2=112_dB+10*LOG(
UVAL(UBASE(K1)))' '
PeakSPL=SPL+10*LOG(
UVAL(UBASE(PEmax)))
' 'Per=Par/\Gno' '\Gno=
10^((SPL-112_dB)/10
)' 'Vd=Sd*xmax' 'Sd
=\pi*(Dia*.83)^2/4' }
Fresp
\<< F Fb / SQ
\-> Fr
\<< Fr DUP
SQ SWAP 1 - SQ Fr
Qb INV SQ * + / LOG
10 *
\>>
\>>
Presp
\<< F Fb / SQ
\-> Fr
\<< Fr 1 -
SQ Fr Qb INV SQ * +
K1 * \Gno / UBASE
\>>
\>>
Vas '10.7_ft^
3'
Qts .33
Fs '30_Hz'
PEmax '200_W'
SPL '95_dB'
Dia '18_in'
xmax '.216_in
'
Vb '
2.47875886772_ft^3'
Qb
.707106781188
Fb '
69.1737579888_Hz'
F3dB '
69.1737579886_Hz'
Fmax '
289.390925206_Hz'
dBpeak '0_dB'
Par '
3.73964138179_W'
Per '
187.42605189_W'
\Gno '
1.99526231497_
Percent'
PeakSPL '
118.010299957_dB'
Sd '
175.303697504_in^2'
Vd '
37.8655986609_in^3'
Amax 1
K1 '
3.73964138179_W'
K2 '
117.728299569_dB'
Vr
4.3166764381
Qr
2.30579193296
F '102.5_Hz'
dBmag '
-21.586698043_dB'
Pmax '
188.735789983_W'
SPLmax '
96.1718445896_dB'
Depth '7.75_
in'
Rdia '8.375_
in'
Xvol '.15_ft^
3'
Ratio
1.61803398875
EQ FREQresp
PPAR {
(0,-12) (200,6) F 0
(0,0) FUNCTION Y }
EQUALIZER
DIR
CIRCUIT
\<< RCLF
CLLCD 2 ENG "R1=" '
1.0824/(C1*\Gw1)'
\->NUM \->STR +
" R8 =" + '(1-k)/k
*R10' \->NUM \->STR + 1
DISP "R2=" '.9239/(
C1*\Gw1)' \->NUM \->STR +
" R9 =" + '(1-k)/
ABS(m)*R10' \->NUM
\->STR + 2 DISP "R3="
'2.613/(C2*\Gw1)'
\->NUM \->STR +
" R10 =" + R10 \->STR
+ 3 DISP "R4=" '
.3827/(C2*\Gw1)' \->NUM
\->STR + " R11 \>=" + '
2*n/(\Gw1*C3)' \->NUM
\->STR + 4 DISP "R5="
'ABS(m)*R6' \->NUM
\->STR + " C1-3=" + 1
ENG C \->STR + 5 DISP
2 ENG "R6=" R6 \->STR
+ " C4 \>=" + '2*n*
C3' \->NUM \->STR + 6
DISP "R7=" '1/(\Gw1*
C3)' \->NUM \->STR + 1
ENG " m= " + m
\->NUM \->STR + 7 DISP
3 FREEZE STOF
\>>
F3dB 16
R 33000
C .000001
n 25
FREQresp
'dBmag=20*LOG(ABS(A
(s)))'
POWresp '
Pmax=Presp/SQ(ABS(A
(s)))'
Presp
\<< F Fb
UBASE UVAL / SQ \->
Fr
\<< Fr
1 - SQ Fr Qb INV SQ
* + K1 * \Gno / UBASE
\>>
\>>
A
\<< \-> s '
1/(1-k)*(1-k*H1(s)+
m*(\Gw1/s)*H1(s))*H2(
s)'
\>>
H1
\<< \-> s '
(s/\Gw1)^2/((s/\Gw1)^2+
.7654*s/\Gw1+1)'
\>>
H2
\<< \-> s '
(s/\Gw1)^2/((s/\Gw1)^2+
1.8478*s/\Gw1+1)'
\>>
\Gw '2*\pi*F'
s 'i*\Gw'
\Gw1 '2*\pi*
F3dB'
\Gwc '2*\pi*
Fb/1_Hz'
k '1-(\Gw1/
\Gwc)^2'
m '\Gw1/(Qb
*\Gwc)-.7654'
C1 C
C2 C
C3 C
R6 R
R10 R
F 16
dBmag
22.434400121
Pmax '
1.07307789402_W'
EQ
FREQresp
PPAR {
(0,-6) (100,24) F 0
(0,0) FUNCTION
dBmag }
CST {
CIRCUIT F3dB R C n
}
END
CST { BCALC
EQUALIZER }
END
PORTED
DIR
FREQresp '
dBmag=Fresp'
POWresp.EQ {
'Pmax=Presp' PEmax
}
SPLresp.EQ {
'SPLmax=Sresp' '
PeakSPL+Fresp' }
DESIGN.EQ { '
Vb=20*Qts^3.3*Vas'
'Fb=(Vas/Vb)^.31*Fs
' 'F3dB=(Vas/Vb)^
.44*Fs' 'dBpeak=20*
LOG(Qts*(Vas/Vb)^.3
/.4)' 'Fmax=(345_m/
s)/(\pi*.83*Dia)' '\Gno
=10^((SPL-112)/10)'
'Sd=\pi*(Dia*.83)^2/4
' 'Vd=Sd*xmax' 'K1=
(4*\pi^3*1.18_kg/m^3)
*Fs^4*Vd^2/345_m/s'
'Par=(3_kg*s/m^4)*
F3dB^4*Vd^2' 'K2=
112_dB+10*LOG(UVAL(
UBASE(K1)))' '
PeakSPL=SPL+10*LOG(
UVAL(UBASE(PEmax)))
' 'Per=Par/\Gno' 'Lv=
(2362_m^2/s^2)*Dv^2
/(Fb^2*Vb)-.73*Dv'
'Dmin=\v/(Fb*Vd*1_s/m
)' }
Fresp
\<< F Fs / SQ
Fb Fs / SQ \-> Fn2 A
\<< A Qts /
Fb 7 / Fs / + 1 A +
Vas Vb / + Fb 7 /
Fs / Qts / + Qts
INV Fb 7 / Fs / + \->
B C D
\<< Fn2
SQ DUP SQ SWAP C
Fn2 * - A + SQ D
Fn2 * B - SQ Fn2 *
+ / LOG 10 *
\>>
\>>
\>>
Presp
\<< F Fs / SQ
DUP SQ Fb Fs / SQ
DUP 97 * 49 / \-> Fn2
Fn4 A E
\<< A Qts /
Fb 7 / Fs / + 1 A +
Vas Vb / + Fb 7 /
Fs / Qts / + Qts
INV Fb 7 / Fs / + \->
B C D
\<< K1 \Gno
/ Fn4 E Fn2 * - A
SQ + / Fn4 C Fn2 *
- A + SQ D Fn2 * B
- SQ Fn2 * + *
UBASE
\>>
\>>
\>>
Sresp
\<< F Fs / SQ
Fb Fs / SQ DUP 97 *
49 / \-> Fn2 A E
\<< Fn2 DUP
SQ DUP SQ SWAP ROT
E * - A SQ + / LOG
10 * K2 +
\>>
\>>
Vas '10.7_ft^
3'
Qts .33
Fs '30_Hz'
PEmax '200_W'
SPL '95_dB'
Dia '18_in'
xmax '.216_in
'
Vb '
5.51454614187_ft^3'
Fb '
36.8436116154_Hz'
F3dB '
40.1592705693_Hz'
Fmax '
289.390925206_Hz'
dBpeak '
5.63229874882E-2_dB
'
Par '
3.00439114363_W'
Per '
150.576248601_W'
\Gno '
1.99526231497_
Percent'
PeakSPL '
118.010299957_dB'
Dmin '
5.95278736648_in'
Dv '6_in'
Lv '
5.80912890373_in'
Sd '
175.303697504_in^2'
Vd '
37.8655986609_in^3'
K1 '
.132296847403_W'
K2 '
103.215494952_dB'
F '50_Hz'
dBmag '
-21.2138986833_dB'
Pmax '
29.8704846312_W'
SPLmax '
88.5385240051_dB'
Depth '7.75_
in'
Rdia '8.375_
in'
Xvol '.2_ft^3
'
Ratio
1.61803398875
EQ FREQresp
PPAR {
(0,-12) (200,6) F 0
(0,0) FUNCTION Y }
CST { BCALC }
END
BCALC
\<< BDISP { {
"DEPTH"
\<< Depth OBJ\->
SWAP DROP \->UNIT
'Depth' STO BDISP
\>> } { "RDIA"
\<< Rdia OBJ\->
SWAP DROP \->UNIT
'Rdia' STO BDISP
\>> } { "XVOL"
\<< Xvol OBJ\->
SWAP DROP \->UNIT
'Xvol' STO BDISP
\>> } { "GOLD"
\<< '(\v/5+1)/2'
EVAL 'Ratio' STO
BDISP
\>> } {
"1.25:1"
\<< 1.25
'Ratio' STO BDISP
\>> } { "CUST"
\<< 'Ratio' STO
BDISP
\>> } } TMENU
\>>
BDISP
\<< .9 Dia * 2 /
Rdia 2 / \-> r1 r2
\<< Depth r1 *
r1 r2 - / \-> h1
\<< h1 Depth
- \-> h2
\<< 'VOL(r1
,h1)-VOL(r2,h2)'
EVAL \-> dvol
\<<
"Dia:" Dia \->STR DUP
SIZE 1 - 2 SWAP SUB
+ " RDia:" + Rdia
\->STR DUP SIZE 1 - 2
SWAP SUB + 1 DISP
"Driver depth:"
Depth \->STR + 2 DISP
"Extra vol:" Xvol
\->STR + 3 DISP "Vt:"
Vb dvol + Xvol +
\->STR + " R:" +
Ratio \->STR + 4 DISP
Vb Xvol + dvol + 3
XROOT \-> w
\<<
"Inside H:" w
Ratio * \->STR + 5
DISP "Dimen- W:" w
\->STR + 6 DISP
"sions D:" w
Ratio / \->STR + 7
DISP 3 FREEZE
\>>
\>>
\>>
\>>
\>>
\>>
VOL
\<< \-> r h '\pi/3*r^
2*h'
\>>
Percent .01
CST { CB PORTED }
END
