@echo off
rem QWK-tiedostojen konvertointiin tarkoitettu batchi
rem -------------------------------------------------
rem Jos käyttäjä ei antanut parametrejä mennään näyttämään ohjeet
if %1x==x goto apua
if not exist %1 goto eiloydy
rem mennään roskis-hakemistoon ja tehdään sinne shit-alihakemisto
c:
cd\roskis
md shit
rem mennään qwk-hakemistoon ja sen alle tehdään tmp-alihakemisto
cd\utils\terminat\offline\qwk
md tmp
rem puretaan parametrinä annettu qwk-tiedosto tmp-alihakemistoon
c:\utils\arcs\zip\pkunzip %1 c:\utils\terminat\offline\qwk\tmp
echo  
rem olemme kiinnostuneita vain MESSAGES.DAT tiedostosta
rem kopioimme sen shit-alihakemistoon .old tarkenteelle (tarkistusta varten)
dir tmp\messages.dat | find "MESSAGES"
copy tmp\messages.dat c:\roskis\shit\messages.old
rem nyt päästään asiaan. konvertoidaan tmp-alihakemistossa oleva messages.dat
rem ibm-merkiston mukaisesti (emme ota varmistuksia /nobak)
c:\utils\asic\finxlate c:\utils\terminat\offline\qwk\tmp\messages.dat /ibm /qwk /nobak
rem nyt saatu uusi messages.dat kopsataan myös shit-alihakemistoon
copy tmp\messages.dat c:\roskis\shit\messages.new
rem tuhotaan alkuperäinen qwk-tiedosto (hui!)
del %1
rem pakataan kaikki rojut tmp-alihakemistosta takaisin qwk-hakemistoon
c:\utils\arcs\zip\pkzip %1 c:\utils\terminat\offline\qwk\tmp\*.*
rem tuhotaan koko tmp-alihakemisto (huom! xdel vastaa deltree käskyä)
xdel tmp
rem näytetään shit-alihakemiston sisältö ja pausetetaan
dir c:\roskis\shit\*.*
pause
rem jos pituudet täsmäsivät homma meni ok ja voimme painaa jotain
rem nappia jolloin shit saa kyytiä (tämä on nyt vain varmuuden
rem vuoksi) Jos nyt jokin olisi mennyt pieleen, niin Ctlr-Breakilla
rem saisi suorituksen poikki ja vanha messages.dat löytyisi shitistä.
cd\roskis
xdel shit
goto loppu
:eiloydy
rem Käyttäjä näpytteli omiaan
echo Sorry! En löydä %1 tiedostoa!
:apua
rem ohjeet karussa lyhykäisyydessään
echo huom huom huom huom huom huom huom huom huom! 
echo ---------------------------------------------
echo Tämä batti ei toimi suoraan vaan sinun pitää
echo editoida se ensin itsellesi sopivaksi !!!!!
echo ---------------------------------------------
echo SYNTAX: QWKCONV qwk-tiedosto
rem loppu hyvin kaikki hyvin
:loppu
rem cd\utils\terminat\offline\qwk
echo