@ECHO OFF
    ECHO OFF

    REM  %1   XMPSETS number
    REM  %2   EXAMPL number
    REM  %3   XMPDAT number
    REM  %4   XMPDAT extension
    REM  %5   I = No input file browsing, L = Lookup, P = Plain,
    REM       S = Sound, T = Trace, X = PEF
    REM
    REM  NOTE: Numbers must be two digits long
    REM
    REM  If POMTEST is set to Y, goes back to BURN.BAT, not XMPSETS.BAT.
    REM  BURN.BAT is used for testing at Pinnacle, and is not included
    REM  in the standard Parse-O-Matic package.

    IF (%5) == () START
    IF (%5) == (S) GOTO SOUND

:MAIN
    MENU POM EXAMPLE%5 1%2 /A
    IF ERRORLEVEL 10 GOTO QUIT
    IF ERRORLEVEL  6 GOTO TRACE
    IF ERRORLEVEL  5 GOTO OUTPUT
    IF ERRORLEVEL  4 GOTO RUN
    IF ERRORLEVEL  3 GOTO SEEPOM
    IF ERRORLEVEL  2 GOTO INPUT
    IF ERRORLEVEL  1 GOTO DOCU

:TRACE
    IF (%5) == (L) GOTO SHOWLOOK
    IF (%5) == (X) GOTO SHOWPEF
    IF EXIST POM.TRC GOTO EOCKTRC
    SHOWSBX POM CKTRC
    GOTO MAIN
:EOCKTRC
    CALL VIEW POM.TRC
    GOTO MAIN

:SHOWLOOK
    CALL VIEW EXAMPL%2.TBL
    GOTO MAIN

:SHOWPEF
    CALL VIEW GENERIC.PEF
    GOTO MAIN

:OUTPUT
    IF EXIST EXAMPL%2.LST GOTO EOCKLST
    SHOWSBX POM CKLST
    GOTO MAIN
:EOCKLST
    CALL VIEW EXAMPL%2.LST
    GOTO MAIN

:RUN
    IF (%2) == (15) GOTO EXAMPL15
    IF (%2) == (03) SET POM=HDRCNTR/TEST
    IF (%2) == (04) SET POM=descrip/price
    IF (%2) == (07) SET POM=ALL
    POM EXAMPL%2.POM XMPDAT%3.%4 EXAMPL%2.LST
    SET POM=
    GOTO MAIN
:EXAMPL15
    POM EXAMPL15.POM XMPDAT0?.TXT EXAMPL15.LST
    GOTO MAIN

:SEEPOM
    CALL VIEW EXAMPL%2.POM
    GOTO MAIN

:INPUT
    IF NOT (%2) == (05) GOTO EOWARN5
    SHOWSBX POM WARN5
:EOWARN5
    IF NOT (%4) == (DBF) GOTO EOWRNDBF
    SHOWSBX POM WRNDBF
:EOWRNDBF
    IF NOT (%4) == (FRL) GOTO EOWRNFRL
    SHOWSBX POM WRNFRL
:EOWRNFRL
    CALL VIEW XMPDAT%3.%4
    GOTO MAIN

:DOCU
    SHOWSBX POM EXAMPL%2.STX
    GOTO MAIN

:SOUND
    MENU POM EXAMPLES 1%2 /A /X
    IF ERRORLEVEL 10 GOTO QUIT
    IF ERRORLEVEL  9 SOUND %1 %2 %3 %4 %5 WHOOP
    IF ERRORLEVEL  8 SOUND %1 %2 %3 %4 %5 TRILL
    IF ERRORLEVEL  7 SOUND %1 %2 %3 %4 %5 PIP
    IF ERRORLEVEL  6 SOUND %1 %2 %3 %4 %5 HUH
    IF ERRORLEVEL  5 SOUND %1 %2 %3 %4 %5 ERROR
    IF ERRORLEVEL  4 SOUND %1 %2 %3 %4 %5 EDGE
    IF ERRORLEVEL  3 SOUND %1 %2 %3 %4 %5 BUZZ
    IF ERRORLEVEL  2 SOUND %1 %2 %3 %4 %5 BIP
    IF ERRORLEVEL  1 SOUND %1 %2 %3 %4 %5 BEEP

:QUIT
    IF (%POMTEST%) == (Y) GOTO DONE
    IF EXIST EXAMPL%2.LST DEL EXAMPL%2.LST
    IF NOT (%5) == (T) GOTO DONE
    IF EXIST POM.TRC DEL POM.TRC

:DONE
    IF NOT (%POMTEST%) == (Y) XMPSETS %1
    SET POMTEST=
    MENU POM BURN 255
    IF ERRORLEVEL 10 GOTO DONE2
    BURN X %2

:DONE2