;*******************************************************************;
; Sciptname..:  Guide.SHW                                           ;
; Revision...:  Feb. 1995, by RMP DATA.                             ;
; Purpose....:  Promotion for DATASHOW, as an example script.       ;
;*******************************************************************;

SET ESCAPEKEY OFF
SET DEBUG ON

;Make sure support files are there
IF NOT FILE "show1.scr" DO JUMPMARK 450
IF NOT FILE "show3.scr" DO JUMPMARK 450
IF NOT FILE "show4.scr" DO JUMPMARK 450
IF NOT FILE "show6.scr" DO JUMPMARK 450
IF NOT FILE "guidekey.shw" DO JUMPMARK 450
IF NOT FILE "guideit.shw" DO JUMPMARK 450

; Create variable to check for support files.
VARIABLE CREATE fileno TYPE NUMBER 1
; This checks all the guide screen files
MARK 10
IF NOT FILE "GUIDE"+fileno+".SCR" DO JUMPMARK 450
MATH fileno=fileno+1
IF fileno LE 14 DO JUMPMARK 10
; Clean up after us
VARIABLE RELEASE ALL

;Create variable to control branching
VARIABLE CREATE place TYPE NUMBER 0

;Create variable for keyboard input
VARIABLE CREATE inkey TYPE KEY
VARIABLE CREATE instr TYPE STRING ""
VARIABLE CREATE mouseuse TYPE NUMBER 0

IF MOUSE DO
   COLOR BACKGROUND 5
   COLOR FOREGROUND 15
   SCREEN CLEAR
   SET CURSOR ON
   GOXY 8 10 DRAW BOX 67 2
   GOXY 9 11
   WRITE "A mouse has been detected. Type 'Y' to use it in certain places:"
   GOXY 74 11 READ KEY inkey
   CASE KEY inkey 121 DO MATH mouseuse = 1
   CASE KEY inkey 89 DO MATH mouseuse = 1
END

;Create a starting point to jump to
MARK 1

COLOR ATTRIBUTE 95
COLOR BACKGROUND 5
COLOR FOREGROUND 15
SCREEN CLEAR

DRAW BOX 79 24

SET CURSOR ON
SET DELAYFACTOR 3
GOXY 22 3 WRITE "T H I S   I S   A   G U I D E   T O"
GOXY 23 5 WRITE "U S I N G   D A T A S H O W . . ."
SET DELAYFACTOR 0

COLOR ATTRIBUTE 84
GOXY 21 7 DRAW LINE 36
GOXY 21 9 DRAW BOX 36 10
GOXY 23 10 WRITE "1. How to use this Guide"
GOXY 23 12 WRITE "2. Your first simple script"
GOXY 23 14 WRITE "3. Your first simple slide show"
GOXY 23 16 WRITE "4. How to use DataShow in general"
GOXY 23 18 WRITE "5. Exit the guide"

MARK 2
SET CURSOR ON
GOXY 23 22 WRITE "Enter your choise (1 to 5):              "
GOXY 51 22 READ KEY inkey

SET CURSOR OFF
CASE KEY inkey 49 DO JUMPMARK 100  ; inkey is 1
CASE KEY inkey 50 DO JUMPMARK 200  ; inkey is 2
CASE KEY inkey 51 DO JUMPMARK 300  ; inkey is 3
CASE KEY inkey 52 DO JUMPMARK 400  ; inkey is 4
CASE KEY inkey 53 DO JUMPMARK 500  ; inkey is 5
GOXY 23 22 WRITE "Error in choise - please select (1 to 5)!"
MUSIC SOUND A 2 200
WAIT 1
JUMPMARK 2

;********************************************************************
;Commands for choise 1. how to use this guide
;********************************************************************
MARK 100
MATH place = 1
DO FILE "guideit.shw"

DO FILE "guidekey.shw"
CASE KEY inkey 445 DO JUMPMARK 500  ; alt+x
JUMPMARK 1

;********************************************************************
;Commands for choise 2. the first simple script
;********************************************************************
MARK 200
DO FILE "guidescr.shw"

DO FILE "guidekey.shw"
CASE KEY inkey 445 DO JUMPMARK 500  ; alt+x
JUMPMARK 1

;********************************************************************
;Commands for choise 3.
;********************************************************************
MARK 300
DO FILE "guidesld.shw"

DO FILE "guidekey.shw"
CASE KEY inkey 445 DO JUMPMARK 500  ; alt+x
JUMPMARK 1

;********************************************************************
;Commands for choise 4.
;********************************************************************
MARK 400
MATH place = 2
DO FILE "guideit.shw"

DO FILE "guidekey.shw"
CASE KEY inkey 445 DO JUMPMARK 500  ; alt+x
JUMPMARK 1

;********************************************************************
;Commands if support files are not found
;********************************************************************
MARK 450
SCREEN CLEAR
GOXY 10 08 DRAW BOX 62 6
GOXY 11 09
WRITE "With this tutorial some files are expected:                  "
GOXY 11 10
WRITE "show1.scr, show3.scr, show4.scr, show6.scr, ...              "
GOXY 11 11
WRITE "Unfortunately they cannot be found in the current directory. "
GOXY 11 12
WRITE "Try to correct the problem, and then run this tutorial again."
GOXY 11 13
WAIT "-- Press any key --"

;********************************************************************
;Commands for exit point
;********************************************************************
MARK 500