echo off
set path=%1:\tg
rem	Please note that the some of the following echo statements have an 
rem	invisible character to help spread out the screen.
:sec2
	echo  
	echo Please insert the Tallgrass Tape Software Diskette in drive A:
	echo  
	pause
	a:
	cd\
	if EXIST tmsinit.com goto sec3
	echo   
	echo Wrong diskette!!
	goto sec2
:sec3
	%1:
	cd \tg
	echo  
	echo Installing your Tallgrass Tape Software.
	echo  
	copy a:*.* %1:\tg /v >NUL:
	if EXIST tgalarm.bat goto skpalarm
	echo  
	echo Making TGALARM.BAT from TGALARMC.BAT.
	echo  
	copy %1:\tg\tgalarmc.bat %1:\tg\tgalarm.bat/v >NUL:
:skpalarm
	C:
	cd \
	if EXIST config.sys goto confnd
	goto nocon
:confnd
	echo  
	echo Copying your Config.sys file.
	echo  
	copy C:\config.sys %1:\tg\config.sys/v >NUL:
:nocon
	%1:
	cd \tg
	echo  
	echo Updating/Creating the Config.sys file with device=%1:\tg\tmsinit.com.
	echo  
	copy %1:\tg\config.sys C:\config.sys/v >NUL:
rem     cfgadd must be on local drive
	cfgadd %1:\tg\tmsinit.com
	C:
	cd \
	if EXIST autoexec.bat goto fndaut
	echo  
	echo Creating an autoexec.bat file.
	echo  
	copy %1:\tg\autot C:\autoexec.bat/v >NUL:
	tgpath %1
rem	need a backup copy of new autoexec.bat 
	copy C:\autoexec.bat C:\autoexec.tg/v >NUL:
	goto remrk
:fndaut
	echo  
	echo Updating and saving your autoexec.bat file.
	echo  
	tgpath %1
	copy C:\autoexec.bat %1:\tg\autoexec.tgt/v >NUL:
rem	pre exec easy before user's autoexec.bat
	echo  
	echo  
	echo Updating your autoexec.bat file temporarily for TG installation.
	echo  
	rename %1:\tg\autot.bat autot.tgs
	copy %1:\tg\autot.tgs+%1:\tg\autoexec.tgt %1:\tg\autot.bat/v >NUL:
	del %1:\tg\autot.tgs
rem	pre exec blanks in saved autoexec.tgs
	echo  
	echo Saving a special TG installation file in the TG subdirectory.
	echo  
	copy %1:\tg\autoexec.tgt %1:\tg\autoexec.tgs/v >NUL:
	copy %1:\tg\autot C:\autoexec.bat/v >NUL:
:remrk
	%1:
	cd \tg
	prom N Y 50 Do you wish to install the Xtree Software? (Y/N)
	if NOT ERRORLEVEL 1 goto copy3
:copy2
	echo  
	echo Please insert Xtree diskette in drive A:
	echo  
	pause
	a:
	cd \
	if EXIST tgxtree.exe goto ok2
	echo   
	echo Wrong diskette!!
	goto copy2
:ok2
	%1:
	cd \tg
	echo  
	echo Installing your new Xtree Software.
	echo  
	copy a:*.* %1:\tg /v >NUL:
:copy3
	echo  
	if EXIST itest.com del %1:\tg\itest.com
	itest/k8/t
	if NOT ERRORLEVEL 1 goto :complete
rem	cover the lower left corner of the ITEST box with another corner
	echo ╚
	echo  
	echo	If there are any problems, please refer to "Setting Up Tallgrass
	echo	Software Version 3.x with Your System".
	echo  
	pause
:complete
	cls
	echo  
	echo ┌─────────────────────────────────────────────────────────────────────────────┐
	echo │                                                                             │
	echo │                   PART ONE OF THE INSTALLATION IS COMPLETE.                 │
	echo │                                                                             │
	echo ├─────────────────────────────────────────────────────────────────────────────┤
	echo │                                                                             │
	echo │        Next, the PREPTAPE program will run after the computer has been      │
	echo │        rebooted.                                                            │
	echo │                                                                             │
	echo │        PREPTAPE will prepare a tape for use and then let the user start     │
	echo │        the backup.                                                          │
	echo │                                                                             │
	echo │                                                                             │
	echo │                                                                             │
	echo │                                   IMPORTANT                                 │
	echo │                                                                             │
	echo │        Now OPEN the door on diskette drive A: and press a key to reboot     │
	echo │        the system.  This will blank the screen and start PREPTAPE.          │
	echo │                                                                             │
	echo │                                                                             │
	echo │                                                                             │
	echo └─────────────────────────────────────────────────────────────────────────────┘
	echo  
	reboot