@echo off
echo.
echo ╔════════════════════════════════════════════════════════╗
echo ║ Multisound Pinnacle/Fiji Old Drivers Cleanup Procedure ║
echo ╚════════════════════════════════════════════════════════╝
echo.
echo Welcome to our Pinnacle/Fiji uninstall utility.  This will help you to remove
echo old Pinnacle/Fiji drivers and other traces from your system and prepare you 
echo to update your system to the latest drivers on this disk.  This uninstall
echo process runs in three phases and requires some user assistance, but don't
echo worry, we'll take it one step at a time and make it as easy as possible.
echo.
echo First we may need to remove some files in your \windows\inf directory.  If
echo you installed an older version of the Pinnacle/Fiji drivers there may be one 
echo or more files that contain device information about the Pinnacle/Fiji cards
echo that is no longer valid.  We will now go through these files and see if they
echo contain references to our cards.  If so, you will be asked to remove that
echo particular file and you should answer "yes" by hitting the "Y" key.
echo.
choice Would you like to proceed with that 
if errorlevel 2 goto :helpout
echo.
echo Ok, then let's begin...
echo.
for %%t in (%windir%\INF\OEM*.INF)    do call clnutils.bat /f pindsp95.drv %%t
for %%t in (%windir%\INF\OTHER\*.INF) do call clnutils.bat /f pindsp95.drv %%t
echo.
echo Now that that's done, let's move on to phase 2.  We will open the Windows 
echo 95 Device Manager for you, and you will need to manually remove all TBS Pro 
echo Series devices (that includes Pinnacle and Fiji) from the device list.
echo.
echo To do this, just click the little plus sign to the left of "Sound, video and 
echo game controllers" to expand that section.  Then click on the first device 
echo that refers to a TBS Pro Series card and click the Remove button underneath.  
echo Answer yes to all questions and keep doing this until all TBS Pro Series 
echo devices have been removed.  Usually there is just one or two of them, but if 
echo you have multiple cards or installed the card more than once there may be 
echo multiple entries.  When you're done with that click OK to close the Device 
echo Manager.
echo.
echo Note: You may need to scroll down in the Device Manager to
echo       find the 'Sound, video and game controllers' section.
echo.
choice Would you like to proceed with that 
if errorlevel 2 goto :helpout
echo.
echo Good, here you go...
control.exe sysdm.cpl,system,1
echo.
pause
echo Great.  Now all that's left is to remove some of the old driver files from 
echo your system, but we'll take care of that for you.  Just in case, we'll run 
echo everything by you, but we strongly recommend that you answer "yes" to all 
echo questions by hitting the "Y" key.
rem echo.
if exist %windir%\SYSTEM\PINDSP.VXD   del /P %windir%\SYSTEM\PINDSP.VXD
if exist %windir%\SYSTEM\PINDSP95.DRV del /P %windir%\SYSTEM\PINDSP95.DRV
if exist %windir%\SYSTEM\PINKZ95.DRV  del /P %windir%\SYSTEM\PINKZ95.DRV
echo.
pause
echo Finally, we will ask you to remove folders and program groups that pertain to
echo the Pinnacle/Fiji cards.  It is necessary to remove these old folders to make
echo sure that all files are updated correctly.  In case you saved some of your
echo personal files into one of these directories you should move them to a 
echo secure location and then proceed with the removal of that folder.

clnutils /b
if not exist %temp%\pinbase.bat goto :0
call %temp%\pinbase.bat
del %temp%\pinbase.bat
call clnutils.bat /d

:0
set pinbase=C:\PINNACLE
call clnutils.bat /d

set pinbase=C:\FIJI
call clnutils.bat /d

set pinbase=C:\TBSPROS
call clnutils.bat /d

set pinbase=C:\TBEACH
call clnutils.bat /d

set pinbase=C:\TBAPPS
call clnutils.bat /d

clnutils /g
if not exist %temp%\pingroup.bat goto :1
call %temp%\pingroup.bat
del %temp%\pingroup.bat
call clnutils.bat /g

:1
set pingroup=Multisound Pinnacle
call clnutils.bat /g

set pingroup=Multisound Fiji
call clnutils.bat /g

set pingroup=Pinnacle Applications
call clnutils.bat /g

set pingroup=Fiji Applications
call clnutils.bat /g

set pingroup=Pinnacle Apps
call clnutils.bat /g

set pingroup=Fiji Apps
call clnutils.bat /g

set pingroup=TBS Pro Audio
call clnutils.bat /g

set pingroup=Turtle Beach Pro Audio
call clnutils.bat /g

echo Congratulations.  You have successfully removed your previous Pinnacle/Fiji 
echo installation.  Now, if your TBS Pro Series card is in PnP mode all you have to 
echo do is restart your system and when Windows asks, point it to the location of 
echo the new drivers.  If your card is in legacy mode you have to run the Add New 
echo Hardware applet from the Windows Control Panel.  
echo.
echo We are confident you will be very satisfied with the new drivers.  Enjoy your 
echo card and thanks for choosing Turtle Beach hardware.
goto :end
:helpout
echo.
echo Ok, no problem.  You can either have a friend help you through this procedure 
echo or call Turtle Beach Tech Support at +1-914-966-2150.  Good luck...
:end
echo.
pause