@echo off
cls
echo UltraSound patch for Shadow Caster
echo Adds UltraSound support to Shadow Caster
echo Does NOT support the Shadow Caster demo
echo.

if [%1] == [] goto usage
if not [%2] == [] goto usage
if not exist %1\raven.exe goto baddir
if exist %1\shadback\raven.exe goto skipback

echo Backing up selected files to %1\shadback
md %1\shadback
copy %1\raven.exe %1\shadback\raven.exe > nul
copy %1\adplay.exe %1\shadback\adplay.exe > nul
copy %1\testvoc.exe %1\shadback\testvoc.exe > nul
copy %1\testxmi.exe %1\shadback\testxmi.exe > nul
copy %1\drivers.cfg %1\shadback\drivers.cfg > nul
copy %1\shadow.bat %1\shadback\shadow.bat > nul
copy %1\*.dll %1\shadback\*.dll > nul

:skipback
echo Copying new files
copy %1\shadback\shadow.bat %1\loadshad.bat > nul
copy shadow.001 %1\shadow.bat > nul
copy gusmid32.dll %1\a32mt32.dll > nul
copy gusmid32.dll %1\a32sbfm.dll > nul
copy gusdig32.dll %1\a32sbdg.dll > nul
copy drivers.cfg %1\drivers.cfg  > nul
copy loadpats.exe %1\loadpats.exe > nul
copy patches.ini %1\patches.ini > nul

echo Patching .EXE files
a32lpat %1\raven.exe > nul
a32lpat %1\adplay.exe > nul
a32lpat %1\testvoc.exe > nul
a32lpat %1\testxmi.exe > nul

cls
echo.
echo.
echo Shadow Caster has been patched.
echo.
echo The Sound drivers have been replaced with UltraSound drivers and the
echo game configured for General MIDI music with Digital Sound.
echo.
echo All modified files have been backed up to %1\shadback
echo.
echo Type SHADOW [ENTER] to play Shadow Caster
echo.
goto end

:baddir
echo Shadow Caster does not appear to be installed in the specified directory.
echo.
goto end

:usage
echo.
echo USAGE:
echo.
echo %0 DIRECTORY
echo.
echo where DIRECTORY is the full drive and path where Shadow Caster is
echo installed. For example:
echo.
echo     a:
echo     %0 C:\SHADOW
echo.
echo would apply patches from the a: diskette drive to the installation
echo in the C:\SHADOW subdirectory
echo.
:end