echo off
if not exist %1\install.ddf goto USAGE
cls
echo ************************************************************************
echo **
echo **             NEW DRIVER INSTALLATION
echo **             1-2-3 Release 3.1  (tm)
echo **
echo **
echo **    This procedure will install new drivers from a supplemental
echo **    drivers distribution disk into your 1-2-3 Release 3 (tm)
echo **    directory and make them available for you to install using the
echo **    1-2-3 Release 3.1 (tm) Install program.
echo **
echo **    READ THE INSTALLATION NOTE IN THE DRIVER INSTALLATION PROGRAM
echo **    BEFORE EXECUTING THIS PROCEDURE
echo **
echo **    Note that the copy of INSTALL.DDF in your 1-2-3 Release 3.1
echo **    directory will be renamed to INSTALL.BAK.
echo **
echo **     Verify that your 123 Release 3.1 directory is:
echo **
echo **                    %1
echo **
echo **    If this is not correct, type Control-Break to quit, and
echo **    start again.
echo **
echo **     Otherwise...
echo **
pause
if not exist %2:*.DDF goto APPENDA
goto APPENDB
 
:USAGE
cls
echo ************************************************************************
echo **
echo **
echo **  To use this batch file, type
echo **
echo **  instdrv a: b
echo **
echo **  where a: is the full path name, including drive letter, of
echo **  your 1-2-3 Release 3.1 directory
echo **
echo **  and b is the drive letter for your distribution disk.  (This
echo **  may be left blank if your disk is in drive a)
echo **
echo **  For example, if your 1-2-3 Release 3.1 directory is c:\123r3 and
echo **  your distribution disk is in drive b, type:
echo **
echo **        instdrv c:\123r3 b
echo **
echo **
echo **  Press Control-Break to quit, or to clean up,...
echo **
pause
goto EXITERR1
 
 
:APPENDA
if not exist a:*.ddf goto USAGE
cls
copy %1\install.ddf %1\install.bak
if errorlevel 1 goto EXITERR1
copy %1\install.ddf+a:*.ddf %1\install.ddf
if errorlevel 1 goto EXITERR2
goto COPYFA
 
:APPENDB
if not exist %2:*.ddf goto USAGE
cls
copy %1\install.ddf %1\install.bak
if errorlevel 1 goto EXITERR1
copy %1\install.ddf+%2:*.ddf %1\install.ddf
if errorlevel 1 goto EXITERR2
goto COPYFB
 
:COPYFA
if not exist a:*.dl? goto COPYFA1
copy a:*.dl? %1\*.*
if errorlevel 1 goto EXITERR2
:COPYFA1
if not exist a:*.pbd goto COPYFA2
copy a:*.pbd %1\*.*
if errorlevel 1 goto EXITERR2
:COPYFA2
if not exist a:*.lrf goto COPYFA3
copy a:*.lrf %1\*.*
if errorlevel 1 goto EXITERR2
:COPYFA3
goto EXITOK
 
:COPYFB
if not exist %2:*.dl? goto COPYFB1
copy %2:*.dl? %1\*.*
if errorlevel 1 goto EXITERR2
:COPYFB1
if not exist %2:*.pbd goto COPYFB2
copy %2:*.pbd %1\*.*
if errorlevel 1 goto EXITERR2
:COPYFB2
if not exist %2:*.lrf goto COPYFB3
copy %2:*.lrf %1\*.*
if errorlevel 1 goto EXITERR2
:COPYFB3
GOTO EXITOK
 
:EXITOK
goto EXIT2
 
:EXITERR1
echo ***
echo ***
echo ***
echo ****** An error has occured...Installation failed ******
goto EXIT3
 
:EXITERR2
echo ***
echo ***
echo ***
echo ****** An error has occured...Cleaning up ******
echo ***
copy %1\install.bak %1\install.ddf
del %1\install.bak
goto EXIT3
 
:EXIT2
echo ***
echo ***
echo ***
echo ******    INSTALLATION COMPLETE      ******
echo ***
echo *** Select Modify Current Selections from the Install program
echo *** menu to add drivers to your 123.DCF configuration file.
echo ***
 
:EXIT3