@echo off
rem  Version 1.0  December 30,1992
echo Hercules Graphite Card (tm) - Windows drivers update.
echo.
if "%1"=="" goto errmes1
if "%2"=="" goto errmes1

rem Detect whether it is a valid Windows directory.
if not exist %2\win.com goto errmes2

rem Detect whether there is a SYSTEM sub-directory.
rem When Windows is on a network, the local Windows directory will
rem have no SYSTEM sub-directory.
if not exist %2\system\win.cnf goto nosystem

set windest=%2\system
goto copying
:nosystem
set windest=%2
:copying

if not exist %windest%\vddagx.386 goto errmes3
echo Copying %1\vddagx.386 to %windest% ...
copy %1\vddagx.386 %windest% /v
echo Copying %1\agx.drv to %windest% ...
copy %1\agx.drv %windest% /v
echo Copying %1\agx64016.drv to %windest% ...
copy %1\agx64016.drv %windest% /v
echo Copying %1\agx64024.drv to %windest% ...
copy %1\agx64024.drv %windest% /v
echo Copying %1\agx80016.drv to %windest% ...
copy %1\agx80016.drv %windest% /v
echo Update completed. Remember to run Windows' SETUP next.
goto exit

:errmes2
echo Invalid Windows directory.
echo.

:errmes1
echo Usage: upwin [source drive:] [Windows directory]
echo    eg. upwin  A:  C:\WINDOWS
goto exit

:errmes3
echo Previous version of Graphite Windows drivers not found.
echo You must have the drivers installed previously to use UPWIN.
goto exit

:exit
echo.